说三道四技术文摘-感悟人生的经典句子
说三道四 > 文档快照

VB如何在Visual Basic中实现异步执行程序

HTML文档下载 WORD文档下载 PDF文档下载
VB如何在Visual Basic中实现异步执行程序
郑州市金博大商务中心B座
郭继胜
---- 使用 Visual Basic 编写应用程序的开发人员一定都遇到过这样的情形:当你的应用程序要完成一个比较大的任务时,并且该任务是那种“独占式”的任务(比如:使用 Visual Basic 的函数 FileCopy 复制一个超过50兆字节的文件),如果不对程序作出特殊的处理,则用户将被迫面对一个象是被“挂起”的窗体,任凭你用鼠标怎样点击也没有任何反应,更糟糕的是当你从屏幕保护程序切换回该程序时会看到程序的窗体变成了一块“白布”,这更加给人一种“死机”的感觉(其实不仅是使用Visual Basic会遇到这种问题,使用其他的开发工具同样会存在,但其各自提供了自己的解决方法,这里我们姑且只讨论Visual Basic,至于其他的开发工具请参考它们的开发文档)。如何避免这种尴尬的界面出现呢?笔者在实践中发现了一种简单的办法,在这里介绍给大家,希望能对您有所帮助。

---- 这种办法是利用 Visual Basic 提供的创建ActiveX 部件的功能设计一个专门完成“大任务”的ActiveX 部件。Visual Basic 从5.0版本开始在创建ActiveX部件方面显示出前所未有的优秀品质。这里对ActiveX部件作如下简单介绍,以期适合不同的读者。Visual Basic所能设计的部件共有两种:一种是可视的部件;另一种是不可视的部件。可视的部件包括ActiveX控件和ActiveX文档,最常见的ActiveX控件比如现今各种高级开发工具(Inprise Delphi,Sybase PowerBuider等)都提供的按纽(Command或Button)、标签(Label)等等,ActiveX控件和窗体一起构成了应用程序与用户交互的界面。ActiveX文档使用在Internet应用程序中。由于我们的问题不涉及到可视的部件,所以这里不再赘述。

---- 不可视的部件又称为代码部件,包括Active DLL部件和ActiveX EXE部件两种。ActiveX部件的另一个名称是ActiveX服务器,之所以被称作服务器是由于ActiveX部件与使用它们的应用程序之间的关系可以被类比为服务器程序与客户端程序之间的关系:ActiveX部件封装了特定的功能或业务规则,应用程序不需要知道ActiveX部件是如何实现这些功能或业务规则的,只需要通过ActiveX部件提供的编程接口(API:Applacation Programming Interface ,ActiveX部件的API是由部件或其类的一系列属性、方法和事件构成的)传递应用程序的要求(通过属性或方法的参数),然后从部件的事件或其类的事件获得执行结果。根据ActiveX部件(ActiveX服务器)的执行方式可以把ActiveX部件分为进程内部件和进程外部件,所谓进程内部件即部件和使用它们的应用程序执行时共享同一个进程;而进程外部件却执行在自己的进程中,也可以这样认为:进程外部件的执行不影响使用它们的应用程序!显然,这个特性正是本文开始面对的那个问题所需要的。在部件中只有ActiveX EXE部件是进程外部件,因此利用这个特性我们可以创建一个ActiveX EXE部件来完成“大任务”,而应用程序窗体只显示一些任务的提示信息,直到ActiveX EXE部件的类的事件提示任务结束为止。这样应用程序就避免了那种呆板的“白布”窗体的出现,而能够响应任何来自用户的操作或者当从那些遮盖住它的程序切换回来时自行刷新。给用户的感觉是程序是在“异步”执行的。(注:关于创建ActiveX部件的详细信息请参考《Visual Basic联机手册》或MSDN文档)

---- 下面我们通过例子来看如何实现这一想法:在这个例子中我们假设应用程序窗体是一个一直显示当前时间的数字时钟,当你使其执行“大任务”直到任务的完成,这期间你会发现数字时钟窗体从来就没有被“挂起”过,仍然能够响应你的拖动操作和不停地显示时间。以下是实现这一程序和ActiveX EXE部件的步骤及源代码(以Visual Basic 6.0中文企业版为例):

---- 一、 创建ActiveX EXE部件(BigJobServer):

---- 步骤一:打开Visual Basic 6.0(或Visual Basic 5.0)新建一个Visual Basic工程,工程类型选择ActiveX EXE,在工程资源管理器中选中工程1,然后在属性窗口中将其名称改为 BigJobServer。

---- 步骤二:为工程添加一个Timer控件的容器窗体(添加窗体通过菜单 工程 >添加窗体 完成)。窗体名称改为 frmClock ;在窗体上放置一个Timer控件(从工具箱中选择Timer控件),名称改为 timClock。

---- 说明:添加该窗体的用意是提供一个执行任务的定时器(Timer控件)

---- 步骤三:设计实现“大任务”的类 BigJob(注:代码部件是通过各种类实现应用程序交给它的任务的,关于类的创建请参考《手册》或MSDN文档)默认情况下当你新建ActiveX EXE部件时Visual Basic为你添加了一个名为Class1的类(要增加类通过菜单 工程>添加类模块 完成),从工程资源管理器中选中Class1,然后在属性窗口中设置如下属性:

---- (名称): BigJob

---- Instancing: 5-MultiUse (可被创建多个实例,详细情况参考《手册》)编写API:为类BigJob添加方法和事件(通过菜单工具 >添加过程完成)部分代码及程序说明如下:

Private frmTimeClock As frmClock '声明定时器容器窗体
Private WithEvents oTimer As Timer '声明定时器(包括其事件)
Public Event JobStart() '声明任务开始事件
Public Event JobEnd() '声明任务结束事件

Private Sub Class_Initialize()
'---- 类初始化事件 ----
'在这里创建定时器窗体 frmTimeClock
'并引用定时器 oTimer
Set frmTimeClock = New frmClock
Load frmTimeClock
Set oTimer = frmTimeClock.timClock
oTimer.Enabled = False
End Sub

Private Sub Class_Terminate()
'类终止事件,释放定时器并卸载定时器窗体
Set oTimer = Nothing
Unload frmTimeClock
End Sub

Public Sub StartJob()
'方法 - 通知执行“大任务”
oTimer.Interval = 100
‘经过0.1秒时间开始执行任务
oTimer.Enabled = True
End Sub

Private Sub doBigJob()
'模拟的“大任务”是这个空耗时间的循环
'显然,这段代码在标准EXE程序中一定会造成“挂起”状态!
Dim lngTemp As Long
Dim lngSum As Long

For lngTemp = 1 To 10000000
lngSum = lngSum + 1
Next
End Sub

Private Sub oTimer_Timer()
'定时器周期到时开始执行任务
oTimer.Enabled = False
RaiseEvent JobStart '触发“开始执行”事件
doBigJob '执行“大任务”
RaiseEvent JobEnd '触发“任务结束”事件
End Sub

---- 现在保存工程:选择菜单 文件>保存工程,根据提示窗口选择合适的文件夹保存所有工程资源(工程文件,窗体文件,类文件)。

---- 二、 使用并调试BigJobServer部件:

---- 步骤一:选择菜单 运行 >全编译执行,可以看到除了Visual Basic进入运行工程 的状态之外看不到任何窗体出现,ActiveX EXE部件的调试比较特殊: 需要在另一个Visual Basic程序中进行。

---- 步骤二:最小化Visual Basic,然后启动另一个Visual Basic的实例,新建一个标 准EXE工程。选择菜单 工程>引用 ,在可引用的部件中我们可以找到 BigJobServer部件,选中该部件,按“确定”按纽返回。这样就建立了 应用程序和部件服务器间的联系。现在可以在这个工程中创建BigJob类 并使用其方法和事件了。

---- 步骤三:在默认的窗体Form1上放置如下控件并设置其属性(方法同前):

类型 名称 标题(Caption属性)
Label lblTime lblTime
Label lblMessage lblMessage
Timer timClock (无)
Command cmdStart 执行任务
步骤四:为该工程编写简单的代码:
Option Explicit
Dim WithEvents myJob As BigJob ‘声明BigJob对象(包括事件)
Private Sub Form_Load()
Set myJob = New BigJob ‘创建BigJob的实例
End Sub

Private Sub Form_Unload(Cancel As Integer)
Set myJob = Nothing '释放对象
End Sub

Private Sub cmdStart_Click()
myJob.StartJob '通知对象执行任务
End Sub

Private Sub myJob_JobStart()
'在对象的“开始”事件中给用户一些提示
lblMessage.Caption = "正在执行任务 ..."
End Sub

Private Sub myJob_JobEnd()
'在对象的“结束”事件中给用户一些提示
lblMessage.Caption = "任务完成!"
End Sub

Private Sub timClock_Timer()
'“数字时钟”在不间断地显示当前时间
lblTime.Caption = Format(Now, "HH:NN:SS")
End Sub

---- 步骤五:保存并运行这个测试工程会看到如下结果:当你按下“执行任务”按纽 后从提示可以知道那个可怕的“大任务”已经开始执行,直到程序提示任 务结束,这期间无论是拖动窗体还是时间的显示均不会受到影响。由此可 见程序被“挂起”的尴尬局面得到了解决。

---- 三、 补充说明:

---- 1、 上述程序在Visual Basic 6.0中文企业版上调试通过。

---- 2、 要在你的程序中实现这种方法,可以改进ActiveX EXE部件。比如在类BigJob中把doBigJob过程替换为你的具体任务;或通过添加属性来传递适当的任务参数等等。

---- 3、 关于ActiveX EXE部件的编译和发布问题,请参考《Visual Basic联机手册》或MSDN文档。
备案号:鲁ICP备13029499号-2 说三道四 www.s3d4.cn 说三道四技术文摘