说三道四技术文摘-感悟人生的经典句子
说三道四 > 文档快照

关于数据报表的打印设置-VB资料

HTML文档下载 WORD文档下载 PDF文档下载
关于数据报表的打印设置-VB资料




数据报表(DataReport)是VB6新增功能之一。用过它的朋友对这个设计器可以说是既爱且恨。尽管它功能强大,但却有个非常致命的缺点:无法在设计环境中改变纸张大小及走向。即使你在程序中使用Printer对象改变纸张大小及打印走向,也解决不了问题。对于非A4纸的报表或是横向打印的报表,连报表预览都不行。

问题的原因是:DR基于系统默认的打印设置创建自己的内部设备环境。而这个设备环境是没有向外界展现的。DR的内部设备环境与VB的Printer对象的内部设备环境是完全不同的,因此改变 打印机对象的属性对DR一点效果也没有。

解决这个问题的笨办法是,在预览或打印时改变系统默认打印机的设置。使用这个方法连自己都会觉得麻烦,更何况是你的用户。没办法,只能通过代码强行改变系统默认打印机的设置来解决。将下面的代码放入一个模块中:

Option Explicit


Public Enum PrinterOrientationConstants
OrientPortrait = 1
OrientLandscape = 2
End Enum
Private Type DEVMODE
dmDeviceName As String * 32
dmSpecVersion As Integer
dmDriverVersion As Integer
dmSize As Integer
dmDriverExtra As Integer
dmFields As Long
dmOrientation As Integer
dmPaperSize As Integer
dmPaperLength As Integer
dmPaperWidth As Integer
dmScale As Integer
dmCopies As Integer
dmDefaultSource As Integer
dmPrintQuality As Integer
dmColor As Integer
dmDuplex As Integer
dmYResolution As Integer
dmTTOption As Integer
dmCollate As Integer
dmFormName As String * 32
dmUnusedPadding As Integer
dmBitsPerPel As Integer
dmPelsWidth As Long
dmPelsHeight As Long
dmDisplayFlags As Long
dmDisplayFrequency As Long
End Type
Private Type PRINTER_DEFAULTS
pDataType As String
pDevMode As Long
DesiredAccess As Long
End Type
Private Type PRINTER_INFO_2
pServerName As Long
pPrinterName As Long
pShareName As Long
pPortName As Long
pDriverName As Long
pComment As Long
pLocation As Long
pDevMode As Long
pSepFile As Long
pPrintProcessor As Long
pDataType As Long
pParameters As Long
pSecurityDescriptor As Long
Attributes As Long
Priority As Long
DefaultPriority As Long
StartTime As Long
UntilTime As Long
Status As Long
cJobs As Long
AveragePPM As Long
End Type

Public Const DMPAPER_A5 = 11

Private Const DM_IN_BUFFER As Long = 8
Private Const DM_OUT_BUFFER As Long = 2
Private Const DM_ORIENTATION As Long = &H1
Private Const DM_PAPERSIZE = &H2&

Private Const PRINTER_ACCESS_ADMINISTER As Long = &H4
Private Const PRINTER_ACCESS_USE As Long = &H8
Private Const STANDARD_RIGHTS_REQUIRED As Long = &HF0000
Private Const PRINTER_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED _
Or _
PRINTER_ACCESS_ADMINISTER Or PRINTER_ACCESS_USE)

Private Declare Sub CopyMemory Lib "kernel32" Alias _
"RtlMoveMemory" _
(hpvDest As Any, hpvSource As Any, ByVal _
cbCopy As Long)

Private Declare Function OpenPrinter Lib "winspool.drv" Alias _
"OpenPrinterA" (ByVal pPrinterName As String, phPrinter As _
Long, pDefault As Any) As Long

Private Declare Function ClosePrinter Lib "winspool.drv" _
(ByVal hPrinter As Long) As Long

Private Declare Function DocumentProperties Lib "winspool.drv" _
Alias "DocumentPropertiesA" (ByVal hWnd As Long, ByVal hPrinter _
As Long, _
ByVal pDeviceName As String, pDevModeOutput As _
Any, _
pDevModeInput As Any, _
ByVal fMode As Long) As Long

Private Declare Function GetPrinter Lib "winspool.drv" _
Alias "GetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
pPrinter As Any, ByVal cbBuf As Long, pcbNeeded As Long) As _
Long

Private Declare Function SetPrinter Lib "winspool.drv" _
Alias "SetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
pPrinter As Any, ByVal Command As Long) As Long

Function SetDefaultPrinterOrientation(ByVal eOrientation As _
PrinterOrientationConstants) As Boolean

Dim bDevMode() As Byte
Dim bPrinterInfo2() As Byte
Dim hPrinter As Long
Dim lResult As Long
Dim nSize As Long
Dim sPrnName As String
Dim dm As DEVMODE
Dim pd As PRINTER_DEFAULTS
Dim pi2 As PRINTER_INFO_2

' 获取默认打印机的设备名称
sPrnName = Printer.DeviceName
' 由于要调用SetPrinter,所以
' 如果是在NT下就要求PRINTER_ALL_ACCESS
pd.DesiredAccess = PRINTER_ALL_ACCESS

' 获取打印机句柄
If OpenPrinter(sPrnName, hPrinter, pd) Then
' 获取PRINTER_INFO_2结构要求的字节数

Call GetPrinter(hPrinter, 2&, 0&, 0&, nSize)
ReDim bPrinterInfo2(1 To nSize) As Byte
lResult = GetPrinter(hPrinter, 2, bPrinterInfo2(1), nSize,nSize)
Call CopyMemory(pi2, bPrinterInfo2(1), Len(pi2))
nSize = DocumentProperties(0&, hPrinter, sPrnName, 0&, 0&, 0)
ReDim bDevMode(1 To nSize)
If pi2.pDevMode Then
Call CopyMemory(bDevMode(1), ByVal pi2.pDevMode, Len(dm))
Else
Call DocumentProperties(0&, hPrinter, sPrnName, bDevMode(1),0&, DM_OUT_BUFFER)
End If

Call CopyMemory(dm, bDevMode(1), Len(dm))
With dm
' 设置新的走向
.dmOrientation = eOrientation
.dmFields = DM_ORIENTATION
'.dmPaperSize = DMPAPER_A5 将纸张大小设为A5,请自行更改所需大小
'.dmFields = DM_PAPERSIZE 必须,否则无法设置纸张大小
End With
Call CopyMemory(bDevMode(1), dm, Len(dm))

Call DocumentProperties(0&, hPrinter, sPrnName, _
bDevMode(1), bDevMode(1), DM_IN_BUFFER Or _
DM_OUT_BUFFER)

pi2.pDevMode = VarPtr(bDevMode(1))

lResult = SetPrinter(hPrinter, 2, pi2, 0&)

Call ClosePrinter(hPrinter)
SetDefaultPrinterOrientation = True
Else
SetDefaultPrinterOrientation = False
End If

End Function
在打印或预览之前直接调用SetDefaultPrinterOrientation 打印走向常数。注意:红色注释部分用于改变纸张的大小。

这个解决方案仍有两个问题:

1。对有些型号的打印机不起作用,例如佳能的BJC-265SP
2。即使是在预浏DR时,也必须改变打印机的设置。这时如果有其它使用打印机默认设 置的程序(如Notepad)要进行打印作业,就可能造成混乱。


尽管如此,这个方法是目前唯一好用的方法。

2014 Shenzhen Maker Faire:国内顶级创客聚会即将举行 若无创新,智能手机将是死路一条 任道远上任VMware中国研发中心总经理 Windows免费,微软方能解救PC市场 Hadoop核心架构HDFS+MapReduce+Hbase+Hive内部机理详解 怎样彻底防止查看源文件 瞧,我們網管的! 问一个非常基础的问题,sql server 2000不能在linux下使用吗??那么在linux下用什么数据库啊?? 新手请教:如何将1补位两位01呢?用什么函数?谢谢大家 简单的程序困扰了我,请指点. 我想学汇编~可不知道什么样的书才适合初学者?? 帮帮忙,为什么我的XmlDoc.Load的时候,报路径非法的错误? 为什么下面的代码运行时通不过? samba的疑问,盼高人! 2、4、6、8……是连续的偶数,若五个连续的偶数的 将1——8这8个数分别填入下面的圆圈里,使每条线上 (1) 图中有大、中、小三个正方形,组成了8个三角 在一些日历牌上,我们可以发现一些日期数所满足的某些 如何用自己的照片制作挂历 如图是某月的日历:如图是某月的日历:(1)带阴影的 这个数阵图怎么填?A 为什么两个连续的自然数,积一定是偶数我想知道准确答 若将十字框上下左右移动,可框住另外五个数,这五个数 俄议员称美国创建了大规模全球性监听系嫦娥三号“月球车”原理样机将亮相上海李克强三大施政要点:寻求平衡 力推改斯诺登撰文称其揭秘行为正确 有助于引时评:外交政策渐失灵 克里七访中东难里约奥运会是里约大冒险?看“生不逢时”的这些车广汽讴歌CDX?为中国量身打造数字真相今日关注七星大帝穿越剑之道仙神之战地球遗弃者星际游商措那湖旅游通天河旅游楚玛尔河旅游将军楼公园旅游察尔汗盐湖旅游
备案号:鲁ICP备13029499号-2 说三道四 www.s3d4.cn 说三道四技术文摘